minv(0).

% maxint: during the competition, maxint will be specified
% externally.
% The first rule below is for when we run the encoding in 
% stand-alone mode.
maxv(1001) :- not other_maxv.
other_maxv :- maxv(X), X!=1001.

cspdomain(fd).

cspvar(time(T),MIN,MAX) :-
	task(T,D),
	minv(MIN), maxv(MAX).


% earliest start
required(time(T) >= EST) :-
	task(T,D),
	est(T,EST).


% latest termination
required(time(T) + D <= LET) :-
	task(T,D),
	let(T,LET).


% overlap (disj)

%
% On Sicstus, use_cumulative appears to be 10%-25% faster than use_inequalities.
% On B-Prolog, use_inequalities appears to be 50% faster than use_cumulative.
% See e.g. 03-disjunctive_scheduling-947-0.asp.
%
%use_cumulative.
use_inequalities.

required(cumulative([time(T1),time(T2)],[D1,D2],[1,1],1)) :-
	use_cumulative,
	disj(T1,T2),
	task(T1,D1),
	task(T2,D2).

required((time(T1)+D1 <= time(T2)) \/ (time(T2)+D2 <= time(T1))) :-
	use_inequalities,
	disj(T1,T2),
	task(T1,D1),
	task(T2,D2).


% precedences
required(time(T1)+D1 <= time(T2)) :-
	task(T1,D1),
	task(T2,D2),
	prec(T1,T2).
