pos(1..N) :- size(N).

constant(1,C) :-
	size(N),
	C=N*(N*N+1)/2.

constant(2,C) :-
	size(N),
	C=N*N+1.

%
% "Output" variables
%
cspvar(sqr(X,Y),1,N*N) :-
	pos(X),
	pos(Y),
	size(N),
	-value_specified(X,Y).

required(sqr(X,Y)==gsqr(X,Y)) :-
	pos(X),
	pos(Y),
	-value_specified(X,Y).

value_specified(X,Y) :-
	sqr(X,Y,V).
-value_specified(X,Y) :-
	pos(X),
	pos(Y),
	not value_specified(X,Y).
%
% End of "output" variables
%



%
% type(semi)
%


cspvar(gsqr(X,Y),1,N*N) :-
	type(semi),
	pos(X),
	pos(Y),
	size(N).

required(all_different([gsqr/2])).




required(gsqr(X,Y)==V) :-
	type(semi),
	sqr(X,Y,V).


required(sum([gsqr(X)/2],==,C)) :-
	type(semi),
	constant(1,C),
	pos(X).



%
% gsqr_yx(Y,X,V): V is the variable encoding the value at <X,Y>
%
gsqr_yx(Y,X,gsqr(X,Y)) :-
	type(semi),
	pos(X),
	pos(Y).

required(sum([gsqr_yx(Y)/3],==,C)) :-
	type(semi),
	constant(1,C),
	pos(Y).




%
% type(normal)
%



%
% gsqr_diag1(X,V): V is the variable encoding
% the value at x=X along the top-left to
% bottom-right diagonal
%
gsqr_diag1(X,gsqr(X,X)) :-
	type(normal),
	pos(X).

required(sum([gsqr_diag1/2],==,C)) :-
	type(normal),
	constant(1,C).



%
% gsqr_diag2(X,V): V is the variable encoding
% the value at x=X along the top-right to
% bottom-left diagonal
%
gsqr_diag2(X,gsqr(X,Y)) :-
	type(normal),
	pos(X), pos(Y),
	size(N),
	Y=N-X+1.

required(sum([gsqr_diag2/2],==,C)) :-
	type(normal),
	constant(1,C).


%
% type(pan)
%

gsqr_br_diag1(D,X,gsqr(X,Y)) :-
	type(pan),
	pos(D), D != 4, % D=4 is the standard diagonal
	pos(X),
	pos(Y),
	size(N),
	Y=((X - D + N - 1) #mod N) + 1.

required(sum([gsqr_br_diag1(D)/3],==,C)) :-
	type(pan),
	pos(D), D != 4, % D=4 is the standard diagonal
	constant(1,C).



gsqr_br_diag2(D,X,gsqr(X,Y)) :-
	type(pan),
	pos(D), D != 4, % D=4 is the standard diagonal
	pos(X),
	pos(Y),
	size(N),
	Y=N - (((X - D + N - 1) #mod N) + 1) + 1.

required(sum([gsqr_br_diag2(D)/3],==,C)) :-
	type(pan),
	pos(D), D != 4, % D=4 is the standard diagonal
	constant(1,C).



%
% type(assoc)
%

required(gsqr(X1,Y1) + gsqr(X2,Y2) == C) :-
	type(assoc),
	pos(X1), pos(Y1),
	pos(X2), pos(Y2),
	size(N),
	%X1 <= X2, Y1 <= Y2,	% symmetry
	Center = ( N + 1 ) / 2, X1 <= Center, % symmetry
	X2 = N - X1 + 1,
	Y2 = N - Y1 + 1,
	constant(2,C).

#hide sqr/3.
