pos(1..N) :- size(N).

constant(1,C) :-
	size(N),
	C=N*(N*N+1)/2.

constant(2,C) :-
	size(N),
	C=N*N+1.


val(1..M) :-
	size(N),
	M=N*N.


%
% type(semi)
%


1{ sqr(X,Y,V) : pos(X) : pos(Y) }1 :- val(V).
:- not 1{ sqr(X,Y,V) : val(V) }1, pos(X), pos(Y).



:- type(semi), constant(1,C), pos(X), not C #sum[ sqr(X,Y,V)=V : pos(Y) : val(V) ] C.
:- type(semi), constant(1,C), pos(Y), not C #sum[ sqr(X,Y,V)=V : pos(X) : val(V) ] C.

:- type(normal), constant(1,C), not C #sum[ sqr(X,X,V)=V ] C.
:- type(normal), constant(1,C), size(N),
   not C #sum[ sqr(X,Y,V)=V : pos(X) : pos(Y) : Y=N-X+1 : val(V) ] C.

:- type(pan), constant(1,C), pos(D), D != 4, size(N),
   not C #sum[ sqr(X,Y,V)=V : pos(X) : pos(Y) : Y=((X - D + N - 1) #mod N) + 1 : val(V) ] C.
:- type(pan), constant(1,C), pos(D), D != 4, size(N),
   not C #sum[ sqr(X,Y,V)=V : pos(X) : pos(Y) : Y=N - (((X - D + N - 1) #mod N) + 1) + 1 : val(V) ] C.

:- type(assoc), constant(2,C), size(N),
   pos(X1), pos(Y1), pos(X2), pos(Y2),
   Center = ( N + 1 ) / 2, X1 <= Center, % symmetry
   X2 = N - X1 + 1,
   Y2 = N - Y1 + 1,
   sqr(X1,Y1,V1), sqr(X2,Y2,V2),
   V1 + V2 != C.
