#base.

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%% Ensure that every goal jet can be pressurized

openPath(J,J) :-
	jet(J), goal(J).
openPath(J,N1) :-
	jet(J), goal(J),
	openPath(J,N2),
	link(N1,N2,V).

canPressurize(J) :-
	jet(J), goal(J),
	tank(T), full(T),
	openPath(J,T).

:- not canPressurize(J), jet(J), goal(J).

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%% Compute number of leaks on each path

lreachable_from_goal(J,0,J,0) :-
	jet(J), goal(J).


#cumulative s.
lreachable_from_goal(N1,NL,J,NS+1) :-
	jet(J), goal(J),
	NS=0..s,
	lreachable_from_goal(N2,NL,J,NS),
	link(N1,N2,V),
	not leaking(V).
lreachable_from_goal(N1,NL+1,J,NS+1) :-
	jet(J), goal(J),
	NL=0..s,
	NS=0..s,
	lreachable_from_goal(N2,NL,J,NS),
	link(N1,N2,V),
	leaking(V).

pressurePath(J,T,NL,NS) :-
	jet(J), goal(J),
	tank(T), full(T),
	lreachable_from_goal(T,NL,J,NS).

-orphan(J,s) :-
	jet(J), goal(J),
	NL<=s,
	pressurePath(J,T,NL,NS).

orphan(J,s) :-
	jet(J), goal(J),
	not -orphan(J,s).

orphans(s) :-
	jet(J), goal(J),
	orphan(J,s).

all_done(s) :-
	not orphans(s).

bestPath(J,T,NL,NS) :- tank(T), full(T), pressurePath(J,T,NL,NS),
	all_done(s),
	jet(J), goal(J),
	-orphan(J,s),
	NL=#min[ pressurePath(J,TK,NLT,NST)=NLT : tank(TK) : full(TK) ].

bestLeak(J,NL) :-
	all_done(s),
	jet(J), goal(J),
	-orphan(J,s),
	NL=#min[ pressurePath(J,TK,NLT,NST)=NLT : tank(TK) : full(TK) ].

bestLen(J,NL,NS) :-
	all_done(s),
	jet(J), goal(J),
	-orphan(J,s),
	bestLeak(J,NL),
	NS=#min[ pressurePath(J,TK,NL,NST)=NST : tank(TK) : full(TK) ].

bestPath(J,T,NL,NS) :-
	all_done(s),
	jet(J), goal(J),
	-orphan(J,s),
	bestLen(J,NL,NS),
	tank(T), full(T),
	pressurePath(J,T,NL,NS).

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%% Determine which valves must be opened
%% (must handle the case in which there are
%% multiple best paths)
%%
poss_use_valve(J,N,V,NL,NS-1) :-
	all_done(s),
	jet(J), goal(J),
	bestPath(J,T,NL,NS),
	tank(T), full(T),
	lreachable_from_goal(N,NL,J,NS-1),
	link(T,N,V),
	not leaking(V).

poss_use_valve(J,N,V,NL-1,NS-1) :-
	all_done(s),
	jet(J), goal(J),
	bestPath(J,T,NL,NS),
	tank(T), full(T),
	lreachable_from_goal(N,NL-1,J,NS-1),
	link(T,N,V),
	leaking(V).

poss_use_valve(J,N2,V2,NL,NS-1) :-
	all_done(s),
	jet(J), goal(J),
	poss_use_valve(J,N1,V1,NL,NS),
	lreachable_from_goal(N2,NL,J,NS-1),
	link(N1,N2,V2),
	not leaking(V2).

poss_use_valve(J,N2,V2,NL-1,NS-1) :-
	all_done(s),
	jet(J), goal(J),
	poss_use_valve(J,N1,V1,NL,NS),
	lreachable_from_goal(N2,NL-1,J,NS-1),
	link(N1,N2,V2),
	leaking(V2).

1{ use_valve(J,N,V,NL,0) : poss_use_valve(J,N,V,NL,0) }1 :-
	all_done(s),
	jet(J), goal(J).

1{ use_valve(J,N2,V2,NL2,S+1) : poss_use_valve(J,N2,V2,NL2,S+1) : link(N2,N1,V1) : not tank(N2) }1 :-
	all_done(s),
	jet(J), goal(J),
	bestLen(J,ML,MS),
	use_valve(J,N1,V1,NL,S),
	S<MS-1.


n_prevActions(J,NP) :-
	all_done(s),
	goal(J),
	NP=#sum[ bestPath(J1,T,NL,N)=N : goal(J1) : J1 < J ].

switchon(V,S-LS-1+NP) :-
	all_done(s),
	goal(J),
	bestPath(J,T,L,S),
	n_prevActions(J,NP),
	use_valve(J,N,V,NL,LS).

#volatile s.
:- orphans(s).

% in case the instance follows...
#base.
